; Orange programmer module v1.4 FASTSPI
; (c) 2006-2011 CnCLab

;CHIP=SST25VF512,64K(128),SST25V010.HPL
;VCC=3000
;CHIP=SST25VF010,128K(128),SST25V010.HPL
;VCC=3000
;CHIP=SST25VF020,256K(128),SST25V010.HPL
;VCC=3000
;CHIP=SST25VF040,512K(128),SST25V010.HPL
;VCC=3000


; SPI SERIAL FLASH MEMORY

;Status Register:    7   6   5   4   3   2   1   0
;                   BPL AAI  X   X  BP1 BP0 WEL BUSY
;					    r/o r/o

; Tested SST25VF010, SST25LF020A, SST25LF040A

INFO="Serial FLASH. Use ERASE before WRITE"

SOCKET=4 ;"SPI"
CDELAY=0.1 ; one set delay 
OPTIONS=f

PINO=SCK,0
PINO=SI,1
PINO=CS,2
PINO=WP,3
PINO=HOLD,4
PINI=SO,1

BUSO=SPIOUT,0xD4
BUSO=SPIOUT24,0xD6
BUSI=SPIIN,0xD4


R9=STATUS,C8,BPL,AAI,x,x,BP1,BP0,WEL,BUSY
;R9=STATUS,B8
R10=ADDRESS,H

[INIT]
HOLD=1
WP=0
CS=1
SCK=0

[_SENDBYTE]
;LOOP=(7,0){SI=R0[I],SCK=P}
;speed-up
SPIOUT=R0

[_SENDADR]
;LOOP=(23,0){SI=ADR[I],SCK=P}
SPIOUT24=ADR

;return R1
[_RDSR]
SCK=0
CS=0
_SENDBYTE(00000101b)     ;RDSR
SI=1
R1=0
LOOP=(7,0){SCK=1,R1[I]=SO,SCK=0}
CS=1

[_WREN]
SCK=0
CS=0
_SENDBYTE(00000110b)   ; Write enable
CS=1

[_WRSR]
R1=R0
SCK=0
CS=0
_SENDBYTE(0x50)      ;EWSR 
CS=1
CS=0
_SENDBYTE(00000001b)      ;WRSR 
R0=R1		     ;Status Register
_SENDBYTE
CS=1



[READ]
CS=0
_SENDBYTE(00000011b)     ;Read
_SENDADR
SI=1
;LOOP=(7,0){SCK=1,DATA[I]=SO,SCK=0}
DATA=SPIIN
CS=1


[READBLOCK]
CS=0
_SENDBYTE(00000011b)     ;Read
_SENDADR
SI=1
LOOP=($BLOCKSIZE){
;LOOP=(7,0){SCK=1,DATA[I]=SO,SCK=0}
DATA=SPIIN
ADR=+1
}
CS=1

[_WAITWR]	;Wait for end write memory...
;P=100000
SCK=0
LOOP=(0,10000){
_RDSR
R1[0]?0{BREAK}   ;WIP bit
P=10
}



[WRITEINIT]
HOLD=1
WP=1
CS=1
P=5000
_WREN

_WRSR(0);         ;Status Register
P=15000	;!

[WRITE]
R0=DATA,R0?0xFF{RETURN}
_WREN
CS=0
_SENDBYTE(00000010b)   ; Write
_SENDADR
_SENDBYTE(DATA);
SI=1,CS=1
;P=5000
_WAITWR

[WRITEBLOCK]
_WREN
CS=0
_SENDBYTE(0xAF)   ; Write + increment
_SENDADR
_SENDBYTE(DATA)
CS=1,P=10
ADR=+1
R3=$BLOCKSIZE
R3=-1
LOOP=(R3){
CS=0
_SENDBYTE(0xAF)   ; Write + increment
_SENDBYTE(DATA)
ADR=+1
CS=1,P=10
}
CS=1

CS=0
_SENDBYTE(0x04)   ;WRDI for terminate AAI
CS=1

_WAITWR


[READID]
WP=1
SCK=0
CS=1
CS=0
R7=0
;1010 1011 ABh Read Manufacturer and Product ID
_SENDBYTE(10101011b)	 ;RID
_SENDBYTE(0)		; DUMMY adr
_SENDBYTE(0)
_SENDBYTE(0)
SI=1
LOOP=(15,0){SCK=1,R7[I]=SO,SCK=0}
CS=1
PRINT=S("ID value = %02lXH",R7)
P=50000
R0=R7


[ReadStatus]
;HOLD=1
WP=1
SCK=0
CS=1
_RDSR
R9=R1
GET=("Status",R9)


[WriteStatus]
GET=("Write Status",R9)
RA?0{EXIT}
WP=1           ;enable
;PRINT=("value %02lX",R9)
_WREN
R0=R9
_WRSR
P=20000


[Erase]
HOLD=1
WP=1
SCK=0
CS=1
_WREN
_WRSR(0)
P=10000
_WREN
CS=0
_SENDBYTE(0x60)		;BE Bulk Erase
CS=1

; Full erase time - 4 sec!
SCK=0
R2=0
LOOP=(0,5000){
CS=0
PRINT=S("Erase %lu",R2)
R2=+1
_RDSR
R1[0]?0{BREAK}   ;RDY bit
P=1000
}

PRINT=S("Erase finished. Status=%02X",R1)
P=500000


[EraseSector]
GET=("Sector Address",R10)
RA?0{EXIT}
HOLD=1
WP=1
SCK=0
CS=1
_WREN
_WRSR(0)
P=10000
_WREN
CS=0
;_SENDBYTE(0x20)		;BE sec Erase
_SENDBYTE(0x52)		;BE BLK Erase
LOOP=(23,0){SI=R10[I],SCK=1,SCK=0}
CS=1
P=10000

; Full erase time - 4 sec!
_WAITWR
SCK=0
R2=0
LOOP=(0,5000){
CS=0
PRINT=S("Erase %lu",R2)
R2=+1
_RDSR
R1[0]?0{BREAK}   ;RDY bit
P=1000
}

PRINT=S("Erase finished. Status=%02X",R1)
P=500000