; Orange programmer module v1.8
; (c) 2009-2012 CnCLab

; Macronix
;CHIP=MX25L3205,4096K(256),mx25l3205.hpl
;AREA=MAIN,4096K(256) 
;AREA=OTP,512(256)
;VCC=3250


; 4K EEPROM not present in MX25L3205D

; tested MX25L3205D

; SPI SERIAL FLASH MEMORY
; Only Main Area support ERASE.

;Status Register:    7   6   5   4    3   2   1   0
;                   SRWD X   X  BP2  BP1 BP0 WEL WIP
;					    r/o  r/o

INFO="Serial FLASH. Use ERASE before WRITE"

SOCKET=4 ;"SPI"
OPTIONS=f,

PINO=SCK,0
PINO=SI,1
PINO=CS,2
PINO=WP,3
PINO=HOLD,4
PINI=SO,1

CDELAY=0.1 ; one set delay 1...0.1us

R9=STATUS,C8,SRWD,x,x,BP2,BP1,BP0,WEL,WIP
;R9=STATUS,B8
R10=ADDRESS,H


[_SENDBYTE]
;LOOP=(7,0){SI=R0[I],SCK=P}
;speed-up
SI=R0[7],SCK=P
SI=R0[6],SCK=P
SI=R0[5],SCK=P
SI=R0[4],SCK=P
SI=R0[3],SCK=P
SI=R0[2],SCK=P
SI=R0[1],SCK=P
SI=R0[0],SCK=P

[_SENDADR]
LOOP=(23,0){SI=ADR[I],SCK=P}


[_WREN]
SCK=0
CS=0
_SENDBYTE(00000110b)   ; Write enable
CS=1

[_WRDI]
SCK=0
CS=0
_SENDBYTE(00000100b)   ; Write disable
CS=1


;return R1
[_RDSR]
SCK=0
CS=0
_SENDBYTE(0x05)     ;RDSR = 05
;R0=0x05,LOOP=(7,0){SCK=0,SI=R0[I],SCK=1}
SI=1

R1=0
LOOP=(7,0){R1[I]=SO,SCK=1,SCK=0}
CS=1


[_WAITWR]	;Wait for end write memory...
SCK=0
LOOP=(0,40000){
_RDSR
R1[0]?0{BREAK}   ;WIP bit
P=5
}


[_WRSR]
R1=R0
SCK=0
CS=0
_SENDBYTE(00000001b) ;WRSR 
_SENDBYTE(R1)	     ;Status Register
CS=1
P=10000
_WAITWR  ;max 500ms

[INIT]
HOLD=1
WP=0
CS=1
SCK=0
P=10

$AREA?1{ ;4KEEP
CS=0
_SENDBYTE(0xA5)     ;EN4K - Enter 4Kb sector
CS=1
}



[READ]
CS=0
_SENDBYTE(3)     ;Read
_SENDADR
SI=1
LOOP=(7,0){SCK=1,DATA[I]=SO,SCK=0}
CS=1
P=1


[READBLOCK]

CS=0
;_SENDBYTE(00000011b)     ;Read
_SENDBYTE(0x0B)     ;Fast Read
_SENDADR
_SENDBYTE(0)	    ; dummy	
SI=1
LOOP=($BLOCKSIZE){
;LOOP=(7,0){SCK=1,DATA[I]=SO,SCK=0}
;speed-up:
SCK=1
R0[7]=SO,SCK=N
R0[6]=SO,SCK=N
R0[5]=SO,SCK=N
R0[4]=SO,SCK=N
R0[3]=SO,SCK=N
R0[2]=SO,SCK=N
R0[1]=SO,SCK=N
R0[0]=SO,SCK=0
DATA=R0

ADR=+1
}
CS=1

[_READBLOCKT]
;$BLOCKSIZE=512 ;dbg
CS=0
_SENDBYTE(00000011b)     ;Read
_SENDADR
SI=1
LOOP=($BLOCKSIZE){
LOOP=(7,0){SCK=1,DATA[I]=SO,SCK=0}
ADR=+1
}
CS=1





[WRITEINIT]
HOLD=1
WP=1
CS=1
P=2000
_WREN
$AREA?0{	 ;WRSR will not be executed in 4kbit mode
_WRSR(0)         ;Status Register clear
P=5000
}

[WRITE]
_WREN
CS=0
_SENDBYTE(00000010b)   ; Write
_SENDADR
_SENDBYTE(DATA);
SI=1,CS=1
P=3000
_WAITWR

[WRITEBLOCK]
_WREN
CS=0
_SENDBYTE(0x02)   ; Write + increment
_SENDADR
LOOP=($BLOCKSIZE){
_SENDBYTE(DATA)
ADR=+1
}
CS=1,SI=1
P=100
_WAITWR



[WRITEEND]
_WRDI

[READID]
WP=1
SCK=0
CS=1
CS=0
R7=0
;1010 1011 ABh Read Manufacturer and Product ID
_SENDBYTE(0x90)	 ;REMS
_SENDBYTE(0)		; DUMMY adr
_SENDBYTE(0)
_SENDBYTE(0)
SI=1,P=100
LOOP=(15,0){SCK=1,R7[I]=SO,SCK=0}
CS=1
PRINT=S("ID value = %02lXH",R7)
P=20000
R0=R7


[ReadStatus]
;HOLD=1
;WP=1 
;_WRDI
;_WREN

WP=0
SCK=0
CS=1
_RDSR
R9=R1
GET=("Status",R9)


[WriteStatus]
GET=("Write Status",R9)
RA?0{EXIT}
WP=1           ;enable
;PRINT=("value %02lX",R9)
_WREN
_WRSR(R9)
P=50000
_RDSR
PRINT=S("Status=%02X",R1)
P=500000



[Erase]
HOLD=1
WP=1
SCK=0
CS=1
_WREN
_WRSR(0)

_WREN
CS=0
_SENDBYTE(0x60)		;BE Bulk Erase
CS=1

R7=$SIZE, R7=/50	;; Full erase time - 64 000 ms (64sec)!
PRINT=P(0,R7)

SCK=0
R2=0
LOOP=(R7){
CS=0
R2=+1
PRINT=P(R2)
_RDSR
PRINT=S("STATUS=%02X",R1)
R1[0]?0{BREAK}   ;RDY bit
P=1000
}
_WRDI
P=200000

[EraseSector]
GET=("Sector Address",R10)
RA?0{EXIT}
HOLD=1
WP=1
SCK=0
CS=1
_WREN
_WRSR(0)

_WREN
CS=0
_SENDBYTE(0x20)		;BE sec Erase
;_SENDBYTE(0x52)		;BE BLK Erase
LOOP=(23,0){SI=R10[I],SCK=1,SCK=0}
CS=1
P=10000

; Full erase time - 4 sec!
_WAITWR
SCK=0
R2=0
LOOP=(0,10000){
CS=0
PRINT=S("Erase %lu",R2)
R2=+1
_RDSR
R1[0]?0{BREAK}   ;RDY bit
P=1000
}
_WRDI
P=200000

[END]
$AREA?1{ ;4KEEP
CS=0
_SENDBYTE(0xB5)     ;EX4K - Exit 4Kb sector
CS=1
}