; Orange programmer module v2.2 FASTSPI
; (c) 2003-2014 CnCLab
; GROUP=ST
; CHIP=M25P10,128K(128),M25P20.HPL
; CHIP=M25P20,256K(256),M25P20.HPL
; CHIP=M25P40,512K(256),M25P20.HPL

; GROUP=Spansion
; CHIP=S25FL001,256K(256),M25P20.HPL
; CHIP=S25FL002,512K(256),M25P20.HPL

; SPI
;VCC=3250

;Status Register:    7   6   5   4   3   2   1   0
;                  WPEN  X   X   X  BL1 BL0 WEL WIP
;					    r/o r/o

SOCKET=4 ;"SPI"
OPTIONS=f
CDELAY=0.1 ; one set delay 

PINO=SCK,0
PINO=SI,1
PINO=CS,2
PINO=WP,3
PINO=HOLD,4
PINI=SO,1

BUSO=SPIOUT,0xD4
BUSO=SPIOUT24,0xD6
BUSI=SPIIN,0xD4

R9=STATUS,C8,WPEN,x,x,x,BL1,BL0,WEL,WIP
;R9=STATUS,B8

[INIT]
HOLD=1
WP=0
CS=1
SCK=0

[_SENDBYTE]
;LOOP=(7,0){SI=R0[I],SCK=P}
;speed-up
SPIOUT=R0

[_SENDADR]
;LOOP=(23,0){SI=ADR[I],SCK=1,SCK=0}
SPIOUT24=ADR



[READ]
CS=0
_SENDBYTE(00000011b)     ;Read
_SENDADR ;LOOP=(23,0){SI=ADR[I],SCK=P}
SI=1
;LOOP=(7,0){SCK=1,DATA[I]=SO,SCK=0}
DATA=SPIIN
CS=1
P=1


[READBLOCK]
CS=0
_SENDBYTE(00000011b)     ;Read
_SENDADR ;LOOP=(23,0){SI=ADR[I],SCK=P}
SI=1
LOOP=($BLOCKSIZE){
;LOOP=(7,0){SCK=1,DATA[I]=SO,SCK=0}
;speed-up:
DATA=SPIIN
ADR=+1
}
CS=1

[_WAITWR]	;Wait for end write memory...
SCK=0
LOOP=(0,500){
CS=0
R0=00000101b,_SENDBYTE     ;RDSR
SI=1
R9=0
LOOP=(7,0){SCK=1,R9[I]=SO,SCK=0}
CS=1
R9[0]?0{BREAK}   ;WIP bit
P=10
}


[_WREN]
SCK=0
CS=0
_SENDBYTE(00000110b)   ; Write enable
CS=1


[WRITEINIT]
HOLD=1
WP=1
CS=1
P=5000
_WREN

CS=0
_SENDBYTE(00000001b)   ;WRSR 
_SENDBYTE(00000000b)      ;Status Register
CS=1
P=50000	;!

[WRITE]
SCK=0
_WREN
CS=0
_SENDBYTE(00000010b)   ; Write
_SENDADR ;LOOP=(23,0){SI=ADR[I],SCK=P}
SPIOUT=DATA  ;LOOP=(7,0){SI=DATA[I],SCK=P}
SI=1,CS=1
;P=5000
_WAITWR

[WRITEBLOCK]
;SCK=0
_WREN
CS=0
_SENDBYTE(00000010b)   ; Write
_SENDADR ; LOOP=(23,0){SI=ADR[I],SCK=P}
LOOP=($BLOCKSIZE){
SPIOUT=DATA  ;LOOP=(7,0){SI=DATA[I],SCK=P}
ADR=+1
}
CS=1
_WAITWR


[ReadID]
WP=1
SCK=0
CS=1
CS=0
R7=0
R0=10101011b	 ;RES
_SENDBYTE
R0=0		; DUMMY adr
LOOP=(23,0){SI=R0[I],SCK=P}
SI=1
LOOP=(7,0){SCK=1,R7[I]=SO,SCK=0}
CS=1
P=10000
PRINT=("ID value = %02lXH",R7)


[ReadStatus]
;HOLD=1
WP=1
SCK=0
CS=1
CS=0
R9=0
R0=00000101b,_SENDBYTE     ;RDSR
SI=1
LOOP=(7,0){SCK=1,R9[I]=SO,SCK=0}
CS=1
P=10000
GET=("Status",R9)

[WriteStatus]
GET=("Write Status",R9)
RA?0{EXIT}
WP=1
CS=1
SCK=0
;PRINT=("value %02lX",R9)

_WREN
CS=0
R0=00000001b      ;WRSR 
_SENDBYTE
R0=R9		     ;Status Register
_SENDBYTE
CS=1
P=200000 ;Write Status Register Time 67... 150 ms

[Erase]
PRINT=S("Erase...")
HOLD=1
WP=1
SCK=0
CS=1
_WREN
CS=0
_SENDBYTE(00000001b)      ;WRSR 
_SENDBYTE(0)	 ;Status Register
CS=1
P=200000 ;Write Status Register Time 67... 150 ms
_WREN
CS=0
R0=11000111b		;BE Bulk Erase
_SENDBYTE
CS=1

; Full erase time: 
; m25p20     - 4 sec
; S25FL016A   10..96 sec

SCK=0
R3=0
PRINT=P(0,20000)
LOOP=(20000){ ;100 sec
CS=0
R0=00000101b,_SENDBYTE     ;RDSR
SI=1
R9=0
LOOP=(7,0){SCK=1,R9[I]=SO,SCK=0}
CS=1
R9[0]?0{BREAK}   ;WIP bit
P=5000
R3=+1
PRINT=P(R3)
}