; Orange programmer module v4.4
; (c) 2004-2013 CnCLab
; Atmel AVR

;CHIP=ATtiny2313,2K,ATT2313.hpl  
;AREA=FLASH,2K(32),0
;AREA=EEPROM,128

; tested: ATTINY2313A,ATTINY2313V
; FLASH PAGE = 32byte

ALLPINS=20
INFO="AVR Adapter"
OPTIONS=mf,   ;FLASH: no modify, skip blank

PINO=SCK,  0,19
PINO=MOSI, 2,17
PINO=MISO, 1,18
PINO=RESET,3,1
PINI=MISO, 1,18

PINO=GND,255,10
PINO=VCC,254,20


BUSO=CFREQ,128

R8=Fuses,B8
R9=Lock,C2,LB2,LB1
R10=CKSEL,L,"0000: Ext Clk,0001: reserved,0010: IntRC 4MHz,0011: reserved,0100: IntRC 8MHz,0101: reserved,0110: Watchdog 128K,0111: reserved,1000: Ceramic,1001: Ceramic,1010: Crystal/Ceramic 0.3-3.0,1011: Crystal/Ceramic 0.3-3.0,1100: Crystal 3-8MHz,1101: Crystal 3-8MHz,1110: Crystal 8-20MHz,1111: Crystal 8-20MHz"
R11=SUT,C2,1,0
R12=CKOUT,L,"0 - On,1 - Off"
R13=CKDIV8,L,"0 - On,1 - Off"


R14=RSTDISBL,L,"0 - PA2:IO,1 - PA2:RST"
R15=BODLEVEL,d
R16=WDTON,L,"0 - On,1 - Off"
R17=SPIEN,L,"0 - On,1 - Off"
R18=EESAVE,L,"0 - Save,1 - Clear"
R19=DWEN,L,"0 - On,1 - Off"

R1A=SELPROGEN,L,"0 - On","1 - Off"


CDELAY=10 ; minimum periods for the serial clock (SCK) > 4 XTAL1 clock cycle!


[!#SETUP]
$WDELAY=6000
R9=0 ;Lock

[_DOUT]
R1=0
LOOP=(7,0){MOSI=R0[I],SCK=1,R1[I]=MISO,SCK=0}

[_DIN]
R0=0
LOOP=(7,0){SCK=1,R0[I]=MISO,SCK=0}

;return R0
[_RDLOCK]
_DOUT(0x58)  ;rd lock bits
_DOUT(0x00) 
_DOUT(0x00) 
_DIN


[INIT]
SCK=0
MISO=Z
CFREQ=2000000 ;2MHz
RESET=0,P=2000

LOOP=(0,31){    ; 32 attempts
RESET=1,P=500
RESET=0,P=15000
_DOUT(0xAC) ;Programming Enable
_DOUT(0x53)
_DOUT(0x00)
R3=R1
_DOUT(0)
R3?0x53{BREAK}
;PRINT=("ANSWER: %02lX",R1)
}
R3?!0x53{PRINT=("ANSWER ERROR: %02lX",R3),EXIT}

P=10
RE?<4{
_RDLOCK
R0=&3,R0?0{PRINT=S("#MCU memory locked!")}
}



[READ]
$AREA?0{
R0=0x20            ;program memory area
R1=ADR,R0[3]=R1[0] ;Hi/Lo
_DOUT
LOOP=(16,9){MOSI=ADR[I],SCK=P}
LOOP=(8,1){MOSI=ADR[I],SCK=P}
}
$AREA?1{
_DOUT(0xA0)      ;eeprom area
LOOP=(15,8){MOSI=ADR[I],SCK=P}
LOOP=(7,0){MOSI=ADR[I],SCK=P}
}

_DIN		;common
DATA=R0

[WRITE]
$AREA?0{
PRINT=("Only Page Write Supported!")
EXIT
}

$AREA?1{
_DOUT(0xC0) ;eeprom memory area
LOOP=(15,8){MOSI=ADR[I],SCK=P}
LOOP=(7,0){MOSI=ADR[I],SCK=P}
R0=DATA,_DOUT
P=$WDELAY ; min 4ms for EEPROM.
}

;Only Flash
[WRITEBLOCK]
R5=ADR
LOOP=($BLOCKSIZE){
R0=0x40 		;program memory
R1=ADR,R0[3]=R1[0],_DOUT 	;Hi/Lo
_DOUT(0)
R0=ADR,R0=/2,_DOUT
_DOUT(DATA)
P=10
ADR=+1
}
;Write Program memory Page:
;R5=+80h	;dbg
ADR=R5

_DOUT (0x4C)
LOOP=(16,9){MOSI=ADR[I],SCK=P}
LOOP=(8,1){MOSI=ADR[I],SCK=P}
_DOUT(0) 		;dummy data
P=$WDELAY   ; min 4.5ms for FLASH.

[WRITEEND]
P=10000
RESET=1,P=20
RESET=0,P=20000



["Read Fuses"]
_DOUT(0x50)	;Read Fuse bits
_DOUT(0x00)
_DOUT(0x00)
_DIN

PRINT=L("FUSE LOW: %02X\n",R0)
R8=R0

R10=0,R11=0,R12=0,R13=0
R10=R8,R10=&0xF	;R10=CKSEL,L
R11[0]=R8[4]    ;R11=SUT,L,1,2,3,4
R11[1]=R8[5]
R12[0]=R8[6]    ;R12=CKOUT,L,On,Off
R13[0]=R8[7]    ;R13=CKDIV8,L,On,Off

_DOUT(0x58)   ;Read Fuse High Bits
_DOUT(0x08)
_DOUT(0x00)
_DIN

PRINT=L("FUSE HI: %02X\n",R0)
R8=R0


R14=0,R15=0,R16=0,R17=0,R18=0,R19=0
R14[0]=R8[0]	;R14=Rstdisbl,C1
R15[0]=R8[1]	;R15=BODLEVEL,L7
R15[1]=R8[2]
R15[2]=R8[3]
R16[0]=R8[4]	;R16=WDTON,C1
R17[0]=R8[5]	;R17=SPIEN
R18[0]=R8[6]	;R18=EESAVE
R19[0]=R8[7]	;R19=DWEN

_DOUT(0x50)	;Read ext Fuse bits
_DOUT(0x08)
_DOUT(0x00)
_DIN
PRINT=L("FUSE EXT: %02X\n",R0)


R1A=R0,R1A=&1
RESET=1,P=10
VCC=0


GET=("Read Fuses",R10,R11,R12,R13,R14,R15,R16,R17,R18,R19,R1A)
;GET=("Read Fuses",R10,R11,R12,R13,R14)


["Write Fuses"]
GET=("Write Fuses",R10,R11,R12,R13,R14,R15,R16,R17,R18,R19,R1A)
RA?0{EXIT}
;PRINT=("%lX",R11)
R10?0{
PRINT=A("This fuse value require Ext. Clock, continue?")
RA?0{EXIT}
}
R19?0{	;DWEN
PRINT=A("This fuse value activate DebugWire and disable SPI prog, continue?")
RA?0{EXIT}
}

R17?1{	;SPIEN
PRINT=A("This fuse value disable SPI prog, continue?")
RA?0{EXIT}
}

R14?0{	;RSTDISBL
PRINT=A("This fuse value disable SPI prog, continue?")
RA?0{EXIT}
}

R8=0

R8=R10,R8=&0xF	;R10=CKSEL,L
R8[4]=R11[0]   ;R11=SUT,L,1,2,3,4
R8[5]=R11[1]
R8[6]=R12[0]   ;R12=CKOUT,L,On,Off
R8[7]=R13[0]   ;R13=CKDIV8,L,On,Off


_DOUT(0xAC)
_DOUT(0xA0)
_DOUT(0x00)
_DOUT(R8)
P=40000

R8=0xFF
R8[0]=R14[0] ;R14=Rstdisbl,C1
R8[1]=R15[0] ;R15=BODLEVEL,L7
R8[2]=R15[1]
R8[3]=R15[2]
R8[4]=R16[0] ;R16=WDTON,C1
R8[5]=R17[0] ;R17=SPIEN
R8[6]=R18[0] ;R18=EESAVE
R8[7]=R19[0] ;R19=DWEN

_DOUT(0xAC)   ;Write High Fuse
_DOUT(0xA8)
_DOUT(0x00)
_DOUT(R8)
P=40000

_DOUT(0xAC)   ;Write ext Fuse
_DOUT(0xA4)
_DOUT(0x00)
_DOUT(R1A)
P=40000


RESET=1,P=20
RESET=0,P=20000


[ReadLock]
_DOUT(0x58) ;Write lock bits
_DOUT(0x00)
_DOUT(0x00)
_DIN
R9=R0
GET=("Lock",R9)

[WriteLock]
GET=("Write Lock",R9)
RA?0{EXIT}
_DOUT(0xAC) ;Write lock bits
_DOUT(0xE0)
_DOUT(0x00)
R0=R9,R0=|0xFC,_DOUT

P=40000
RESET=1,P=20
RESET=0,P=20000

[READID]
_DOUT(0x30)
_DOUT(0x00)
_DOUT(0x00)
_DIN
R2=R0,R2=<<8

_DOUT(0x30)
_DOUT(0x00)
_DOUT(0x01)
_DIN
R2=|R0,R2=<<8

_DOUT(0x30)
_DOUT(0x00)
_DOUT(0x02)
_DIN
R0=|R2

;R2?0x1E910A{PRINT=("ID: %06lX - ATTiny2313",R2),RETURN}
PRINT=S("ID: %06lX",R0)



[Erase]
_DOUT(0xAC) ;Chip Erase
_DOUT(0x80)
_DOUT(0x00)
_DOUT(0x00)

P=100000


; Check
_DOUT(0x20)     ;program memory area
_DOUT(0x00) 	;ADR 0
_DOUT(0x00)
_DIN		;common
R0?!0xFF{PRINT=E("Erase error")}

R0?0xFF{PRINT=S("Erase finished")}
RESET=1,P=2000
RESET=0,P=500000



[END]
RESET=1
;EO=1,P=10 ;BB off