; Orange programmer module v3.7 beta
; (c) 2001-2005 CnCLab,  Evimix 
; Atmel AVR
;CHIP=ATmega162,16K,ATM162.hpl
;AREA=FLASH,16K(128),0,0
;AREA=EEPROM,512

; Primary tested


ALLPINS=40
OPTIONS=mf,   ;FLASH: no modify, skip blank
INFO="AVR Adapter"

PINO=SCK,  0,8
PINO=MOSI, 2,6 
PINO=MISO, 1,7 
PINO=RESET,3,9 
PINI=MISO, 1,7 

PING=GND,255,20
PINO=VCC,254,40

BUSO=CFREQ,128

R8=Fuses,B8
; for 88
R9=Lock,C6,BLB12,BLB11,BLB02,BLB01,LB2,LB1

R10=CKSEL,L,"0000: Ext Clk,0001: IntRC 1MHz,0010: IntRC 2MHz,0011: IntRC 4MHz,0100: IntRC 8MHz,0101: ExtRC 0.9MHz,0110: ExtRC 0.9-3.0M,0111: ExtRC 3.0-8.0M,1000: ExtRC 8.0-12.0M,1001: LowFreq Crystal,1010: Crystal/Ceramic,1011: Crystal/Ceramic,1100: Crystal 0.4-0.9,1101: Crystal 0.9-3.0,1110: Crystal 3.0-8.0,1111: Crystal 3.0-8.0"
;R11=SUT,L,00,01,10,11
R11=SUT,C2
R12=CKOUT,L,"0 - On,1 - Off"
R13=CKDIV8,L,"0 - On,1 - Off"
R1A=BOOTRST,L,"0 - Boot Loader","1 - Application"
R1B=BOOTSZ,L,"16 pages,8 pages,4 pages,2 pages"
R14=BODLEVEL,L,"000: reserved,001: reserved,010: reserved,011: reserved,100: 4.3V,101: 2.7V,110: 1.8V,111: Disabled"
R15=EESAVE,L,"0 - Save,1 - Clear"
R16=WDTEN,L,"0 - On,1 - Off"
R17=SPIEN,L,"0 - Enable,1 - Disable"

R18=JTAGEN,L,"0 - On,1 - Off"
R19=OSDEN,L,"0 - On,1 - Off"
R7=M161CEN,L,"0 - On,1 - Off"



CDELAY=10 ; minimum periods for the serial clock (SCK) > 4 XTAL1 clock cycle!


[_DOUT]
R1=0;
LOOP=(7,0){MOSI=R0[I],SCK=1,R1[I]=MISO,SCK=0}

[_DIN]
R0=0
LOOP=(7,0){SCK=1,R0[I]=MISO,SCK=0}


[INIT]
SCK=0
MISO=Z
CFREQ=2000000
RESET=0,P=1000

LOOP=(0,31){    ; 32 attempts
RESET=1,P=150
RESET=0,P=20000
R0=0xAC,_DOUT ;Programming Enable
R0=0x53,_DOUT
R0=0x00,_DOUT
R3=R1
R0=0x00,_DOUT
R3?0x53{BREAK}
;PRINT=("ANSWER: %02lX",R1)
}
R3?!0x53{PRINT=("ANSWER ERROR: %02lX",R3),EXIT}

P=10



[READ]
$AREA?0{
R0=0x20            ;program memory area
R1=ADR,R0[3]=R1[0] ;Hi/Lo
_DOUT
LOOP=(16,9){MOSI=ADR[I],SCK=P}
LOOP=(8,1){MOSI=ADR[I],SCK=P}
}
$AREA?1{
R0=0xA0      ;eeprom area
_DOUT
LOOP=(15,8){MOSI=ADR[I],SCK=P}
LOOP=(7,0){MOSI=ADR[I],SCK=P}
}

_DIN		;common
DATA=R0


[WRITE]
$AREA?0{
PRINT=("Only Page Write Supported!")
EXIT
}

$AREA?1{
R0=0xC0 ;eeprom memory area 
_DOUT
LOOP=(15,8){MOSI=ADR[I],SCK=P}
LOOP=(7,0){MOSI=ADR[I],SCK=P}
R0=DATA,_DOUT
P=9000 ; 4ms
}


[WRITEBLOCK]
R7=ADR	
;check empty (0xFF) block
LOOP=($BLOCKSIZE){
R1=DATA
R1?!0xFF{BREAK}
ADR=+1
}
R1?0xFF{RETURN}
ADR=R7           ;restore

LOOP=($BLOCKSIZE){
R0=0x40 ;Load program memory
R1=ADR,R0[3]=R1[0],_DOUT 	;Hi/Lo
_DOUT(0)
LOOP=(8,1){MOSI=ADR[I],SCK=P}
R0=DATA,_DOUT
P=10
ADR=+1
}
;Write Program memory Page:
ADR=R7		;restore
_DOUT(0x4C) 
LOOP=(16,9){MOSI=ADR[I],SCK=P}
LOOP=(8,7){MOSI=ADR[I],SCK=P}
LOOP=(6,1){MOSI=0,SCK=P}
_DOUT(0) 		;dummy data
P=10000

[WRITEEND]
P=10000
RESET=1,P=20,
RESET=0,P=20000


["Read Fuses"]
_DOUT(0x50)	;Read Fuse Low bits
_DOUT(0x00)
_DOUT(0x00)
_DIN
R8=R0


R10=0,R11=0,R12=0,R13=0
R10=R8,R10=&0xF	;R10=CKSEL,L
R11[0]=R8[4]    ;R11=SUT,L,1,2,3,4           
R11[1]=R8[5]
R12[0]=R8[6]    ;R12=CKOUT,L,On,Off            
R13[0]=R8[7]    ;R13=CKDIV8,L,On,Off  
        

_DOUT(0x58)   ;Read Fuse High Bits
_DOUT(0x08)
_DOUT(0x00)
_DIN
R8=R0

R15=0,R16=0,R17=0,R18=0,R19=0,R1A=0,R1B=0
R1A[0]=R8[0]	;R1A=BOOTRST
R1B[0]=R8[1]	;R1B=BOOTSZ
R1B[1]=R8[2]	;R1B=BOOTSZ
R15[0]=R8[3]	;R15=EESAVE
R16[0]=R8[4]	;R16=WDTON
R17[0]=R8[5]	;R17=SPIEN
R18[0]=R8[6]	;R18=JTAGEN
R19[0]=R8[7]	;R19=OSDEN

_DOUT(0x50)   ;Read Fuse ext Bits
_DOUT(0x08)
_DOUT(0x00)
_DIN
R8=R0

R14=0,R7=0
R14[0]=R8[1]	;R14=BODLEVEL
R14[1]=R8[2]	;R14=BODLEVEL
R14[2]=R8[3]	;R14=BODLEVEL

R7[0]=R8[4]	;R7=M161CEN

RESET=1,P=10
VCC=0


GET=("Read Fuses",R10,R11,R12,R13,R1A,R1B,R14,R15,R16,R17,R18,R19,R7)
;GET=("Read Fuses",R10,R11,R12,R13,R14)


["Write Fuses"]
GET=("Write Fuses",R10,R11,R12,R13,R1A,R1B,R14,R15,R16,R17,R18,R19,R7)
RA?0{EXIT}
;PRINT=("%lX",R11)
R10?0{
PRINT=A("This fuses value require Ext. Clock, continue?")
RA?0{EXIT}
}

;R19?0{
;PRINT=A("This fuses value disable serial prog., continue?")
;RA?0{EXIT}}

R8=0

R8=R10,R8=&0xF	;R10=CKSEL,L
R8[4]=R11[0]    ;R11=SUT,L,1,2,3,4           
R8[5]=R11[1]
R8[6]=R12[0]    ;R12=CKOUT,L,On,Off    
R8[7]=R13[0]    ;R13=CKDIV8,L,On,Off   

R0=0xAC,_DOUT	;Write Low Fuse
R0=0xA0,_DOUT
R0=0x00,_DOUT
R0=R8,_DOUT
P=15000

R8=0xFF

R8[0]=R1A[0] 	;R1A=BOOTRST
R8[1]=R1B[0] 	;R1B=BOOTSZ
R8[2]=R1B[1] 	;R1B=BOOTSZ
R8[3]=R15[0] 	;R15=EESAVE         
R8[4]=R16[0] 	;R16=WDTON            
R8[5]=R17[0] 	;R17=SPIEN            
R8[6]=R18[0] 	;R18=JTAGEN            
R8[7]=R19[0] 	;R19=OSDEN            


R0=0xAC,_DOUT   ;Write High Fuse
R0=0xA8,_DOUT
R0=0x00,_DOUT
R0=R8,_DOUT
P=15000

R8=0xFF

R8[1]=R14[0] 	;R14=BODLEVEL
R8[2]=R14[1]	;R14=BODLEVEL
R8[3]=R14[2]	;R14=BODLEVEL
R8[4]=R7[0]	;R7=M161CEN

R0=0xAC,_DOUT   ;Write Ext Fuse
R0=0xA4,_DOUT
R0=0x00,_DOUT
R0=R8,_DOUT
P=15000


RESET=1,P=20
RESET=0,P=20000


[ReadLock]
_DOUT(0x58) ;Read lock bits
_DOUT(0x00) 
_DOUT(0x00) 
_DIN
R9=R0
;PRINT=("R9: %04lX",R9)
GET=("Lock",R9)

[WriteLock]
GET=("Write Lock",R9)
RA?0{EXIT}
_DOUT(0xAC) ;Write lock bits
_DOUT(0xE0) 
_DOUT(0x00) 
R0=R9,R0=|0xC0
;PRINT=("R9: %04lX",R9)
_DOUT 

P=50000
RESET=1,P=20,
RESET=0,P=10000

[ReadID]
R0=0x30,_DOUT
R0=0x00,_DOUT
R0=0x00,_DOUT
_DIN
R2=R0,R2=<<8

R0=0x30,_DOUT
R0=0x00,_DOUT
R0=0x01,_DOUT
_DIN
R2=|R0,R2=<<8

R0=0x30,_DOUT
R0=0x00,_DOUT
R0=0x02,_DOUT
_DIN
R2=|R0

R2?0x1E9401{PRINT=("ID: %06lX - ATmega161",R2),EXIT}
R2?0x1E9402{PRINT=("ID: %06lX - ATmega163",R2),EXIT}
R2?0x1E9403{PRINT=("ID: %06lX - ATmega16",R2),EXIT}
R2?0x1E9404{PRINT=("ID: %06lX - ATmega162",R2),EXIT}
PRINT=("ID: %06lX",R2)


[Erase]
R0=0xAC,_DOUT ;Chip Erase
R0=0x80,_DOUT 
R0=0x00,_DOUT 
R0=0x00,_DOUT 

P=50000
RESET=1,P=20,
RESET=0,P=10000



[END]
RESET=1
;EO=1,P=10 ;BB off