; Orange programmer module v2.3
; (c) 2008-2014 CnCLab
; SPI FLASH

;GROUP=EON
;CHIP=EN25B40,512K(256),EN25B80.HPL
;VCC=3250
;CHIP=EN25B40T,512K(256),EN25B80.HPL
;VCC=3250
;CHIP=EN25B80,1024K(256),EN25B80.HPL
;VCC=3250
;CHIP=EN25B80T,1024K(256),EN25B80.HPL
;VCC=3250
;CHIP=EN25B16,2048K(256),EN25B80.hpl 
;VCC=3250
;CHIP=EN25F16,2048K(256),EN25B80.hpl 
;VCC=3250

;tested: EON EN25B40-50HCP, EON EN25B40-75GCP, EN25S40, EN25F16, EN25D80

; EN25BXX -  Boot Sector
; EN25FXX -  Uniform Sector
; read, write, erase = M25P40
; ID = SST25V010.hpl 

;Status Register:    7   6   5   4   3   2   1   0
;                  SRP   X   X  BP2 BP1 BP0 WEL WIP
;					    r/o r/o

SOCKET=4 ;"SPI"
OPTIONS=f

PINO=SCK,0
PINO=SI,1
PINO=CS,2
PINO=WP,3
PINO=HOLD,4
PINI=SO,1

CDELAY=0.1 ; one set delay 

R9=STATUS,C8,SRP,x,x,BP2,BP1,BP0,WEL,WIP
;R9=STATUS,B8

[INIT]
HOLD=1
WP=0
CS=1
SCK=0

[_SENDBYTE]
LOOP=(7,0){SI=R0[I],SCK=P}

[READ]
CS=0
_SENDBYTE(00000011b)     ;Read
LOOP=(23,0){SI=ADR[I],SCK=P}
SI=1
LOOP=(7,0){SCK=1,DATA[I]=SO,SCK=0}
CS=1
P=1


[READBLOCK]
CS=0
_SENDBYTE(00000011b)     ;Read
LOOP=(23,0){SI=ADR[I],SCK=P}
SI=1
LOOP=($BLOCKSIZE){
;LOOP=(7,0){SCK=1,DATA[I]=SO,SCK=0}
;speed-up
SCK=1
R0[7]=SO,SCK=N
R0[6]=SO,SCK=N
R0[5]=SO,SCK=N
R0[4]=SO,SCK=N
R0[3]=SO,SCK=N
R0[2]=SO,SCK=N
R0[1]=SO,SCK=N
R0[0]=SO,SCK=0
DATA=R0
ADR=+1
}
CS=1

[_WAITWR]	;Wait for end write memory...
SCK=0
LOOP=(0,5000){
CS=0
_SENDBYTE(00000101b)     ;RDSR
SI=1
R9=0
LOOP=(7,0){SCK=1,R9[I]=SO,SCK=0}
CS=1
R9[0]?0{BREAK}   ;WIP bit
P=10
}


[_WREN]
SCK=0
CS=0
_SENDBYTE(00000110b)   ; Write enable
CS=1


[WRITEINIT]
HOLD=1
WP=1
CS=1
P=5000
_WREN

CS=0
_SENDBYTE(00000001b)   ;WRSR 

_SENDBYTE(00000000b)      ;Status Register
CS=1
P=50000	;!

[WRITE]
SCK=0
_WREN
CS=0
_SENDBYTE(00000010b)   ; Write
LOOP=(23,0){SI=ADR[I],SCK=P}
LOOP=(7,0){SI=DATA[I],SCK=P}
SI=1,CS=1
;P=5000
_WAITWR

[WRITEBLOCK]
SCK=0
_WREN
CS=0
_SENDBYTE(00000010b)   ; Write
LOOP=(23,0){SI=ADR[I],SCK=P}
LOOP=($BLOCKSIZE){
LOOP=(7,0){SI=DATA[I],SCK=P}
ADR=+1
}
CS=1
_WAITWR


[READID]
WP=1
SCK=0
CS=1
CS=0
R7=0
;_SENDBYTE(10101011b)	 ;RID
_SENDBYTE(90H)	 	 ;Manufacturer/Device ID
_SENDBYTE(0)		 ;DUMMY 
_SENDBYTE(0)     	 ;DUMMY 
_SENDBYTE(0)             ;DUMMY 
SI=1
LOOP=(15,0){SCK=1,R7[I]=SO,SCK=0}
CS=1

; EN25B40(Bottom Boot) =  1C32
; EN25B40T(Bottom Boot) = 1C42
; EN25B40(Bottom Boot) =  1C33
; EN25B40T(Bottom Boot) = 1C43
PRINT=S("ID value = %04lXH",R7)
P=50000
R0=R7


[ReadStatus]
;HOLD=1
WP=1
SCK=0
CS=1
CS=0
R9=0
_SENDBYTE(00000101b)     ;RDSR
SI=1
LOOP=(7,0){SCK=1,R9[I]=SO,SCK=0}
CS=1
P=10000
GET=("Status",R9)

[WriteStatus]
GET=("Write Status",R9)
RA?0{EXIT}
WP=1
CS=1
SCK=0
;PRINT=("value %02lX",R9)

_WREN
CS=0
R0=00000001b      ;WRSR 
_SENDBYTE
R0=R9		     ;Status Register
_SENDBYTE
CS=1
P=200000 ;Write Status Register Time 67... 150 ms

[Erase]
PRINT=S("Erase...")
HOLD=1
WP=1
SCK=0
CS=1
_WREN
CS=0
_SENDBYTE(00000001b)      ;WRSR 
_SENDBYTE(0)	 ;Status Register
CS=1
P=200000 ;Write Status Register Time 67... 150 ms
_WREN
CS=0
R0=11000111b		;BE Bulk Erase
_SENDBYTE
CS=1

; Full erase time: 
; m25p20     - 4 sec
; S25FL016A   10..96 sec

SCK=0
R3=0
PRINT=P(0,20000)
LOOP=(0,20000){ ;100 sec
CS=0
R0=00000101b,_SENDBYTE     ;RDSR
SI=1
R9=0
LOOP=(7,0){SCK=1,R9[I]=SO,SCK=0}
CS=1
R9[0]?0{BREAK}   ;WIP bit
P=5000
R3=+1
PRINT=P(R3)
}