; Orange programmer module v2.5
; (c) 1999-2004 CnCLab
; CHIP=34C02 (256x8)
; AT34C02,CAT34WC02,M34C02,NM34C02,NM34W02
; Orange3,4,5,SE

;Tested: AT34C02

INFO="Write Protection for the First-Half of the Array"
SOCKET=1 ;"I2C"

PING=SCL,0
PING=SDA,1
PINO=WP, 2
PINO=A0, 3
PINO=A1, 4
PINO=A2, 5


CDELAY = 4 ; one set delay

R0=I2CADR,H
R9=PROTECT,L,Off,On

[!#SETUP]
R0=0xA0
$WDELAY=25000

[_START]
SDA=1,SCL=1,SDA=0,SCL=0               ; Start  10
SDA?1{
P=200
SDA?1{PRINT=E("SDA line error 1"),EXIT}
}

[_STOP]
SCL=0,SDA=0,SCL=1,SDA=1               ; Stop   01
SDA?0{P=200}


[INIT]
A0=0,R3=R0,R3=&2,R3?2{A0=1}	;setup pins
A1=0,R3=R0,R3=&4,R3?4{A1=1}
A2=0,R3=R0,R3=&8,R3?8{A2=1}
WP=1,P=10

R1=R0   ; read I2C address const
R1=+1

[READ]
_START

LOOP=(7,0) {SDA=R0[I],SCL=1,SCL=0}  ; out 8 bits 0xA0
SDA=0,SDA=1,SCL=1,SDA?0             ; ack check
SCL=0,SDA=0

LOOP=(7,0) {SDA=ADR[I],SCL=1,SCL=0}    ; out 8 bits
SDA=0,SDA=1,SCL=1,SDA?0              ; ack check
SCL=0,SDA=0

_START
LOOP=(7,0){SDA=R1[I],SCL=1,SCL=0}    ; out 8 bits 0xA1
SDA=0,SDA=1,SCL=1,SDA?0              ; ack check
SCL=0

SDA=1                               ;SDA Hi-Z
LOOP=(7,0){SCL=1,DATA[I]=SDA,SCL=0} ;read byte
SDA=1,SCL=1,SCL=0,SDA=0             ;master not asked

SCL=0,SCL=1,SDA=1                   ;stop

[WRITEINIT]
WP=0

[WRITE]
_START
LOOP=(7,0) {SDA=R0[I],SCL=1,SCL=0} ; out 8 bits 0xA0
SDA=0,SDA=1,SCL=1,SDA?0             ; ack check
SCL=0,SDA=0

LOOP=(7,0){SDA=ADR[I],SCL=1,SCL=0}   ; out 8 bits address
SDA=0,SDA=1,SCL=1,SDA?0             ; ack check
SCL=0,SDA=0

LOOP=(7,0){SDA=DATA[I],SCL=1,SCL=0}  ; out 8 bits data
SDA=0,SDA=1,SCL=1,SDA?0             ; 0 - ack check?
SCL=0,SDA=0
SCL=0,SCL=1,SDA=1                  ;stop
P=$WDELAY


["READ PROTECT"]
_START
R8=R0,R8=^0xC0	        	    ; Special address!	
;PRINT=("R8=%02X",R8)
LOOP=(7,0) {SDA=R8[I],SCL=1,SCL=0}  ; out 8 bits 0x60
SDA=0,SDA=1,SCL=1

R9=0	
R9[0]=SDA             ; ack 
SCL=0,SDA=0
GET=("Read Protect",R9);